\\ ---------------  GP code  ---------------------------------------
\\
\\ Time-stamp: <Thu, Dec 19, 2002 - 11:10:35 - apacetti>
\\
\\-----------------------------------------------------------------




\\ etaf calculates Dedekind's eta function on forms [a,b,c] i.e:
\\ eta(tau), where tau = (b+sqrt(-d))/(2a) and d= b^2-4ac.  ett does
\\ the calculation in the fundamental domain and etaf first does a
\\ reduction keeping track of the multiplier.

\\ Used to compute explicit elliptic units in ring class fields but
\\ can be used on its own.


\\======================================================================

etaf(q)=
   {local(d,sqx,a,b,c,aux,mult,n24,n,aa,z);
		      d=4*q[1]*q[3]-q[2]^2;
                      mult=1;
                      n24=0;
                      a=q[1];b=q[2];
                      if(c==0,c=(b*b+d)/(4*a),c=q[3]);
                      if(sqx==0,sqx=sqrt(-b^2+4*a*c),);
                      aa=2*a;
                                 n=(a+b)\aa;
                                 if(n,
                                     aux=a*n;
                                     c=c+(aux-b)*n;
                                     b=b-2*aux;
                                     n24=n24+n;
                                    ,);
                             while(c<a,
                                       mult=mult/sqrt( (sqx-I*b)/aa);
                                       aux=c;c=a;
                                       a=aux;aa=2*a;
                                       b=-b;
                                       n=(a+b)\aa;
                                       if(n,
                                           aux=a*n;
                                           c=c+(aux-b)*n;
                                           b=b-2*aux;
                                           n24=n24+n;
                                          ,);
                                    );
                          z=ett(a,b,sqx)*mult*exp(2*Pi*I*n24/24);
                           z
}
\\======================================================================

ett(a,b,sqx)=
     {local(z,t1,t2,q1,q2,q3,ttau,eps);
			   z=1;t1=1;t2=1;
			   eps=1/10^precision(sqrt(1));
                       ttau=Pi*(I*b-sqx)/a;
                       q1=exp(ttau);
                       q2=exp(2*ttau);
                       q3=exp(3*ttau);
                                until(abs(q1)<eps,
                                       t1=-t1*q1;t2=-t2*q2;
                                       z=z+t1+t2;
                                       q1=q1*q3;q2=q2*q3;
                                      );
                       z*exp(ttau/24)

}

{helpetafunction()=
print("-------------------------------------------------------------------");
print("      		Computational number Theory                        "); 
print("-------------------------------------------------------------------");
print("");
print("Description: Routine for computing the eta function on CM points");
print("");
print("Original Author:     Fernando Rodriguez-Villegas");
print("                     villegas@math.utexas.edu");
print("                     University of Texas at Austin");
print("");
print("With the assistance of:  Ariel Pacetti");
print("                         apacetti@math.utexas.edu");
print("                         University of Texas at Austin");
print("-------------------------------------------------------------------");
print("");
print("List of routines'");
print("");
print("etaf");
print("");
}

addhelp(etaf,"etaf calculates Dedekind's eta function on forms [a,b,c] i.e: eta(tau), where tau = (b+sqrt(-d))/(2a) and d= b^2-4ac.  ett does the calculation in the fundamental domain and etaf first does a reduction keeping track of the multiplier.");