\\ ---------------  GP code  ---------------------------------------
\\
\\ Time-stamp: <Mon, Jan 13, 2003 - 14:17:26 - apacetti>
\\
\\ Description: Some general routines, including some vectors
\\ necessary routines.
\\
\\
\\ Original Author:         Ariel Pacetti
\\			    apacetti@math.utexas.edu
\\			    University of Texas at Austin
\\
\\ Created:             Wed Oct  4  2000
\\

\\======================================================================
\\ Given a vector, and an index i, removes the i-th coordinate

vectorkill(v,i)=
	{local(ans);
	vector(length(v)-1,x,if(x<i,v[x],v[x+1]))
}

\\======================================================================
\\ Routine for given a vector, obtain a new one, ordered, and without 
\\ repetition of elements.

veclistelem(v)=
	{local(aux,ans);
	ans=vecsort(v);
	aux=[];
	for(k=1,length(v)-1,if(ans[k]==ans[k+1],aux=concat(aux,k)));
	for(k=1,length(aux),ans=vectorkill(ans,aux[length(aux)-k+1]));
	ans
}

\\======================================================================
\\ Given a vector, answers the first position whether the element
\\ appears. If the element isn't on the vector, answers []

vectorfind(v,elmnt)=
	{for(k=1,length(v),if(v[k]==elmnt,return(k)));
	[]}

\\======================================================================
\\ Given a vector, switches the elements of the places i and j, where
\\ w is the vector [i,j].

vectorswitch(v,w)=
	{local(aux);
	aux=v;
	aux[w[1]]=v[w[2]];aux[w[2]]=v[w[1]];aux}

\\======================================================================
\\ Given a number, answers all the primes of the factorization

factprimes(n)=
	{local(list);
	list=veclistelem(factor(n)[,1]~);
	if(list[1]==-1,list=vectorkill(list,1));
	list
}

\\======================================================================
\\ Given a number N, and a base b, gives the vector representation of
\\ N in base b.

base(N,b)=
	{local(n,ans);
	ans=[];
	while(N>=b,
		ans=concat(N%b,ans);
		N=(N-N%b)/b);
	ans=concat(N,ans)}
\\======================================================================
\\ Given a prime number, computes some non-quadratic residue

nonquadratic(p)=
	{local(aux);
	aux=2;
	while(kronecker(aux,p)==1,aux=aux+1);
	aux}

\\======================================================================
\\ Given a vector, answers the first position whether the element
\\ appears. If the element isn't on the vector, answers []

vectorfindall(v,elmnt)=
	{local(ans);
	ans=[;];
	for(k=1,length(v),if(v[k]==elmnt,ans=concat(ans,k)));
	ans}
\\======================================================================
\\Given a positive integer n, kills the n-th row of the matrix.

matkillrow(M,n)=matrix(matsize(M)[1]-1,matsize(M)[2],i,j,if(i<n,M[i,j],M[i+1,j]))

\\======================================================================
\\Given a positive integer n, kills the n-th column of the matrix.

matkillcolumn(M,n)=matrix(matsize(M)[1],matsize(M)[2]-1,i,j,if(j<n,M[i,j],M[i,j+1]))

\\----------------------------------------------------------------------
{helproutines()=
print("-------------------------------------------------------------------");
print("      		Computational number Theory                        "); 
print("-------------------------------------------------------------------");
print("");
print("Description: some usefull general routines ");
print("");
print("Original Authors:     Fernando Rodriguez-Villegas");
print("                     villegas@math.utexas.edu");
print("                     University of Texas at Austin");
print("");
print("                      Ariel Pacetti");
print("                      apacetti@math.utexas.edu");
print("                      University of Texas at Austin");
print("-------------------------------------------------------------------");
print("");
print("Help functions");
print("");
print("helpvectorkill     helpveclistelem     helpvectorfind");
print("helpvectorswitch     helpfactprimes     helpbase     helpnonquadratic");
print("");
}

addhelp(vectorkill,"Given a vector v, and an index i, answers v, removing the i'th coordinate")

addhelp(veclistelem,"Given a vector v, answers a new vector, with the elements ordered, and without repetition of elements")

addhelp(vectorfind,"Given a vector v, and some element k, searchs if k is one element of v, and if it is, answers the coordinate number")

addhelp(vectorswitch,"Given a vector v, and a two component vector w=[i,j], switches the i-th and j-th coordinate of the vector v")

addhelp(factprimes,"Given a number n, answers a vector with the primes that divide it")

addhelp(base,"Given a number n, and a base b, answers a vector with the digits of n in base b")

addhelp(nonquadratic,"Given a prime number p, computes the first non-quadratic residue")