/*************** -*- Mode: MACSYMA; Package: MAXIMA -*-  ******************/
/***************************************************************************
***                                                                    *****
***     Copyright (c) 1984 by William Schelter,University of Texas     *****
***     All rights reserved                                            *****
***************************************************************************/


/* rtest3 */						
kill(all);
done;
FOR A FROM -3 STEP 7 THRU 26 DO LDISPLAY(A);
DONE$
S:0;
0$
FOR I WHILE I <= 10 DO S:S+I;
DONE$
S;
55$
SERIES:1;
1$
TERM:EXP(SIN(X));
%E^SIN(X)$
FOR P UNLESS P > 7 DO
    (TERM:DIFF(TERM,X)/P,SERIES:SERIES+SUBST(X = 0,TERM)*X^P);
DONE$
SERIES;
X^7/90-X^6/240-X^5/15-X^4/8+X^2/2+X+1$
POLY:0;
0$
FOR I THRU 5 DO (FOR J FROM I STEP -1 THRU 1 DO POLY:POLY+I*X^J);
DONE$
POLY;
5*X^5+9*X^4+12*X^3+14*X^2+15*X$
GUESS:-3.0;
-3.0$
FOR I THRU 10 DO
    (GUESS:SUBST(GUESS,X,0.5*(X+10/X)),
     IF ABS(GUESS^2-10) < 5.0E-5 THEN RETURN(GUESS));
-3.162280701754386;
/* -3.1622806$ */
FOR COUNT FROM 2 NEXT 3*COUNT THRU 20 DO LDISPLAY(COUNT);
DONE$
X:1000;
1000$
THRU 10 WHILE X # 0 DO X:0.5*(X+5/X);
DONE$
X;
2.28242904$
REMVALUE(X);
[X]$
NEWTON(F,GUESS):=BLOCK([NUMER,Y],LOCAL(F,DF,X,GUESS),NUMER:TRUE,
       DEFINE(DF(X),DIFF(F(X),X)),
       DO (Y:DF(GUESS),IF Y = 0 THEN ERROR("derivative at",GUESS,"is zero"),
	   GUESS:GUESS-F(GUESS)/Y,
	   IF ABS(F(GUESS)) < 5.0E-6 THEN RETURN(GUESS)));
NEWTON(F,GUESS):=BLOCK([NUMER,Y],LOCAL(F,DF,X,GUESS),NUMER:TRUE,
       DEFINE(DF(X),DIFF(F(X),X)),
       DO (Y:DF(GUESS),IF Y = 0 THEN ERROR("derivative at",GUESS,"is zero"),
	   GUESS:GUESS-F(GUESS)/Y,
	   IF ABS(F(GUESS)) < 5.0E-6 THEN RETURN(GUESS)))$
SQR(X):=X^2-5.0;
SQR(X):=X^2-5.0$
NEWTON(SQR,1000);
2.236068027062195; 
FOR F IN [LOG,RHO,ATAN] DO LDISP(F(1.0));
DONE$
EV(CONCAT(E,LINENUM-1),NUMER);
E10$
KILL(FUNCTIONS,VALUES,ARRAYS);
DONE$
DONE;
DONE$
EXP:DIFF(X*F(X),X);
X*'DIFF(F(X),X,1)+F(X)$
F(X):=SIN(X);
F(X):=SIN(X)$
EV(EXP,DIFF);
SIN(X)+X*COS(X)$
X;
X$
X:3;
3$
X;
3$
'X;
X$
F(X):=X^2;
F(X):=X^2$
'F(2);
'F(2)$
EV(%,F);
4$
'(F(2));
F(2)$
F(2);
4$
SUM(I!,I,1,4);
33$
'SUM(I!,I,1,4);
'SUM(I!,I,1,4)$
REMVALUE(X);
[X]$
'INTEGRATE(F(X),X,A,B);
'INTEGRATE(X^2,X,A,B)$
FOR I THRU 5 DO S:S+I^2;
DONE$
EXP:S;
S+55$
EV(%,S:0);
55$
EV(EXP);
S+110$
EXP:'SUM(G(I),I,0,N);
'SUM(G(I),I,0,N)$
Z*%E^Z;
Z*%E^Z$
EV(%,Z:X^2);
X^2*%E^X^2$
SUBST(X^2,Z,EXP);
'SUM(G(I),I,0,N)$
A:%;
'SUM(G(I),I,0,N)$
A+1;
'SUM(G(I),I,0,N)+1$
KILL(A,Y);
DONE$
A;
A$
DECLARE(INTEGRATE,NOUN);
DONE$
INTEGRATE(Y^2,Y);
INTEGRATE(Y^2,Y)$
''INTEGRATE(Y^2,Y);
Y^3/3$
F(Y):=DIFF(Y*LOG(Y),Y,2);
F(Y):=DIFF(Y*LOG(Y),Y,2)$
F(Y):=1/Y;
F(Y):=1/Y$
C10;
C10$
(X+Y)^3;
(Y+X)^3$
DIFF(%,X);
3*(Y+X)^2$
Y:X^2+1;
X^2+1$

/* begin fix */
kill(all);
done;
 EV(%E^X*SIN(X)^2,EXPONENTIALIZE);
 -%E^X*(%E^(%I*X)-%E^-(%I*X))^2/4;
  integrate(%,X);
-(%E^((2*%I+1)*X)/(2*%I+1)+%E^((1-2*%I)*X)/(1-2*%I)-2*%E^X)/4; 
 EV(%,DEMOIVRE);
 -(%E^X*(%I*SIN(2*X)+COS(2*X))/(2*%I+1)
      +%E^X*(COS(2*X)-%I*SIN(2*X))/(1-2*%I)-2*%E^X)
      /4;
 ANS:EV(%,RATEXPAND);
 -%E^X*SIN(2*X)/5-%E^X*COS(2*X)/10+%E^X/2;
 EV(ANS,X:1,NUMER)-EV(ANS,X:0,NUMER);
 0.5779160182042402;
 block([FPPREC:35],EV(ANS,X:1,BFLOAT)-EV(ANS,X:0,BFLOAT));
 5.7791601820424019599988308251707781339427227258443B-1;
 INTEGRATE(%E^X*SIN(X)^2,X);
 -(2*%E^X*SIN(2*X)+%E^X*COS(2*X)-5*%E^X)/10;
 trigreduce(%);
 -(2*%E^X*SIN(2*X)+%E^X*COS(2*X)-5*%E^X)/10;
 % - ans,ratsimp;
 0 ;

/* end fix*/

EV(SIN(X),%EMODE);
SIN(X)$
SIN(%PI/12)+TAN(%PI/6);
SIN(%PI/12)+1/SQRT(3)$
EV(%,NUMER);
0.8361693142921465;
/* tops 20 : 0.83616931$ */
SIN(1);
SIN(1)$
EV(SIN(1),NUMER);
0.8414709848079;
BETA(1/2,2/5);
BETA(1/2,2/5)$
EV(%,NUMER);
3.679092654997149;
/* tops 20: 3.67909265$ */
DIFF(ATANH(SQRT(X)),X);
1/(2*(1-X)*SQRT(X))$
FPPREC:25;
25$
SIN(5.0B-1);
4.794255386042030002732879B-1$
/*begin fix */
 EXP:COS(X)^2-SIN(X)^2;
 COS(X)^2-SIN(X)^2$
 EV(%,X:%PI/3);
 -1/2$
 DIFF(EXP,X);
 -4*COS(X)*SIN(X)$
 INTEGRATE(EXP,X);
 (SIN(2*X)/2+X)/2-(X-SIN(2*X)/2)/2$
 EXPAND(%);
 SIN(2*X)/2$
 TRIGEXPAND(%);
 COS(X)*SIN(X)$
 TRIGREDUCE(%);
 SIN(2*X)/2$
 diff(%,X);
 COS(2*X)$
 %-exp,trigreduce,ratsimp;
  0;
/*end fix*/
SECH(X)^2*SINH(X)*TANH(X)/COTH(X)^2+COSH(X)^2*SECH(X)^2*TANH(X)/COTH(X)^2
				   +SECH(X)^2*TANH(X)/COTH(X)^2;
SECH(X)^2*SINH(X)*TANH(X)/COTH(X)^2+COSH(X)^2*SECH(X)^2*TANH(X)/COTH(X)^2
				   +SECH(X)^2*TANH(X)/COTH(X)^2$
TRIGSIMP(%);
(SINH(X)^5+SINH(X)^4+2*SINH(X)^3)/COSH(X)^5$